Exemples de jeux de données Cast3M

* fichier : source4.dgibi
* section : thermique
*----------------------------------------------------------------------*
*                       S O U R C E 4 . D G I B I                      *
*----------------------------------------------------------------------*
*
* Objet :
* -------
*
* Verfication / validation d'un modele de source de chaleur.
* Cas d'une SOURCE GAUSSIENNE ELARGIE
*
* Description :
* -------------
* Comparaison des flux nodaux equivalents obtenus avec le modele a
* ceux obtenus en construisant le champ "a la main", puis en l'integrant
* avec l'operateur SOURCE.
*
* Type de calcul : Aucun
* Mode de calcul : 3D
* Type d'element : CUB8
* Objectifs      : Ecart relatif entre flux integres < 1.e-12
*                  Ecart relatif entre la chaleur totale fournie (QTOT)
*                  et la resultante sur le champ integre < 1.e-4
*
*----------------------------------------------------------------------*
*
* IG1 vrai : traces actives
IG1      = faux ;
*
* Parametres du maillage :
lo1      = 30.e-3 ;
la1      = 30.e-3 ;
ep1      = 20.e-3 ;
de1      = 0.5e-3 ;
 
* Parametres de la source :
QT1      = 1.e3 * pi ;
RG1      = 5.e-3 ;
ZG1      = 9.e-3 ;
LG1      = 3.e-3 ;
 
*------------------------ 3D ELEMENTS LINEAIRES -----------------------*
*
opti dime 3 elem cub8 ;
 
* Maillage :
li1      = (0 0 0) droi (0 la1 0) dini de1 dfin de1 ;
Su1      = li1     tran (lo1 0 0) dini de1 dfin de1 ;
Vo1       = Su1 volu tran (0 0 ep1) dini de1 dfin de1 ;
 
si IG1 ;
  ltyp1    = Vo1 elem type ;
  mot1     = mot 'ELEM =' ;
  repe bm1 (dime ltyp1) ;
    mot1     = chai mot1 ' ' (ltyp1 extr &bm1) ;
  fin bm1 ;
  mot1     = chai ' Maillage test en 3D (' mot1 ')' ;
  trac cach Vo1 titr mot1 ;
fins;
 
* Parametres de la source :
OR1      = ((0.5 0.5 0.) * (la1 * pi / 3.)) plus (0 0 ep1) ;
DR1      = 0. 0. +2. ;
DL1      = 2. 2. -1. ;
 
* Modeles :
moq1     = mode Vo1 thermique source gaussienne elargie ;
maq1     = mate moq1 'QTOT' QT1 'ORIG' OR1 'RGAU' RG1 'DIRE' DR1 'ZGAU' ZG1 'DIRL' DL1 'LGAU' LG1 ;
sq1      = sour moq1 maq1 ;
qtmoq1   = sq1 resu maxi ;
 
* Repere local :
DL1      = DL1 moin ((psca DL1 DR1) * DR1 / (psca DR1 DR1)) ;
w1       = DR1 / (norm DR1) ;
v1       = DL1 / (norm DL1) ;
u1       = pvec v1 w1 ;
 
* Solution "analytique" : Construction du champ "Gaussien"
mo1      = mode Vo1 thermique ;
x1 y1 z1 = Vo1 coor ;
x1 y1 z1 = (x1 - (or1 coor 1)) (y1 - (or1 coor 2)) (z1 - (or1 coor 3)) ;
x1 y1 z1 = (chan cham x1 mo1 stresses) (chan cham y1 mo1 stresses) (chan cham z1 mo1 stresses) ;
xu1      = (x1 * (u1 coor 1)) + (y1 * (u1 coor 2)) + (z1 * (u1 coor 3)) ;
yv1      = (x1 * (v1 coor 1)) + (y1 * (v1 coor 2)) + (z1 * (v1 coor 3)) ;
zw1      = (x1 * (w1 coor 1)) + (y1 * (w1 coor 2)) + (z1 * (w1 coor 3)) ;
masql0   = (abs yv1) masq egin LG1 ;
masql1   = (abs yv1) masq supe LG1 ;
sqref0   = (((xu1 ** 2 / RG1 / RG1) + (zw1 ** 2 / ZG1 / ZG1) * -2.) exp) * masql0 ;
yl1      = (yv1 abs) born mini LG1 ;
yl1      = yl1 - LG1 ;
sqref1   = (((xu1 ** 2 / RG1 / RG1) + (yl1 ** 2 / RG1 / RG1) + (zw1 ** 2 / ZG1 / ZG1) * -2.) exp) * masql1 ;
chref1   = sqref0 + sqref1 ;
 
* Facteur de normalisation q0 :
xqx2     = ((pi ** 3 / 32.) ** 0.5 * RG1 * RG1 * ZG1) + (0.5 * pi * RG1 * ZG1 * LG1) ;
q0ref    = QT1 / xqx2 ;
 
* Champ de la source de chaleur :
chref1   = chref1 * q0ref ;
 
* Puissance totale qtref1 :
qtref1   = intg chref1 mo1 ;
 
* Flux nodaux equivalents sol. ref.
sqref1   = sour mo1 chref1 ;
 
* Affichages ;
si ig1 ;
  trac chref1 mo1 titr 'Reference distribution Gaussienne "elargie"' ;
  titr 'Reference distribution Gaussienne "elargie"' ;
  trac chref1 mo1 coup or1 (or1 plus v1) (or1 plus w1) ;
 
  trac sqref1 Vo1 titr ' Flux nodaux REFERENCE source Gaussienne' coup or1 (or1 plus v1) (or1 plus w1) ;
  trac sq1    Vo1 titr ' Flux nodaux MODELE    source Gaussienne' coup or1 (or1 plus v1) (or1 plus w1) ;
  trac (sq1 - sqref1) Vo1 titr ' Difference des 2 champs' coup or1 (or1 plus v1) (or1 plus w1) ;
fins ;
 
* calcul erreurs & test :
err0     = abs ((maxi (resu sqref1)) - Qt1) / QT1 ;
err1     = (maxi abs (sq1 - sqref1)) / (maxi abs sqref1) ;
err2     = (abs (qtmoq1 - qt1)) / (abs qt1) ;
opti echo 0 ; saut 1 lign ;
mess (chai format '(F6.3)' ' ***** Erreur relative solution de reference discretisee =' (100. * err0) ' %') ;
mess (chai format '(F6.3)' ' ***** Erreur relative modele / reference discretises    =' (100. * err1) ' %') ;
mess (chai format '(F6.3)' ' ***** Erreur relative modele / puissance tot. specifiee =' (100. * err2) ' %') ;
saut 1 lign ; opti echo 1 ;
 
si ((err0 > 1.e-4) ou (err1 > 1.e-12) ou (err2 > 1.e-4)) ;
  ERRE ' Probleme MODE SOURCE' ;
fins ;
 
 
*----------------- F I N    S O U R C E 4 . D G I B I -----------------*
fin ;