Exemples de jeux de données Cast3M

* fichier : mazars_triaxial.dgibi
************************************************************************
*      Cas test elementaire pour la loi d'endommagement de Mazars      *
*           Essai de compression sous confinement (triaxial)           *
*                                                                      *
* Les donnees experimentales servant de reference sont issues de :     *
* "Study of the Behavior of Concrete under Triaxial Compression"       *
* Domingo Sfer, Ignacio Carol, Ravindra Gettu, Guillermo Etse          *
* Journal of Engineering Mechanics, 2002, 128(2): 156-163              *
* doi : 10.1061/(ASCE)0733-9399(2002)128:2(156)                        *
*                                                                      *
* Le test est realise avec plusieurs modes de calcul :                 *
*   1) 3D volumique                                                    *
*   2) 2D axisymetrique                                                *
*                                                                      *
* ITRAC1 : VRAI => affichage resultats                                 *
* IPSC1  : VRAI => affichage resultats dans un PostScript Couleur      *
************************************************************************
 
DIVERS = 'VENV' 'CASTEM_DIVERS' ;
FIC1   = 'CHAI' DIVERS '/mazars_triaxial_0MPa_courbe0.csv';
FIC2   = 'CHAI' DIVERS '/mazars_triaxial_1.5MPa_courbe0.csv';
FIC3   = 'CHAI' DIVERS '/mazars_triaxial_4.5MPa_courbe0.csv';
FIC4   = 'CHAI' DIVERS '/mazars_triaxial_9MPa_courbe0.csv';
 
** Options pour les traces
ITRAC1 = FAUX ;
IPSC1  = VRAI ;
SI IPSC1 ;
  OPTI 'TRAC' 'PSC' ;
FINSI ;
 
** Liste des modes de calcul a traiter
lcas = LECT 1 2 ;
*nh145313
*lcas = LECT 1 ; COMM '3D volumique' ;
*lcas = LECT 2 ; COMM '2D axisymetrique' ;
 
** Parametres geometriques
rayo = 75.E-3 ;
long = rayo * (pi ** 0.5) ;
haut = 300.E-3 ;
 
** Parametres materiau
you   = 27.3E9 ;
nu    = 0.2 ;
epd0  = 1.E-5 ;
at    = 1. ;
ac    = 1.1 ;
bt    = 10000. ;
bc    = 1200. ;
beta  = 1. ;
 
** Parametres chargement
lpres = PROG 0. 1.5E6 4.5E6 9.E6 ;
umax  = 0.015 * haut ;
 
** Legende courbes
tpre = TABL ;
tleg = TABL ;
tleg . 'TITRE' = TABL ;
 
*nh145313 .csv recuperes => resext = vrai
resexp = vrai ;
 
 
 
 
**************** C A S  #1  :  3 D   V O L U M I Q U E ****************
SI (EXIS lcas 1) ;
 
** Options generales
  OPTI 'DIME' 3 'MODE' 'TRID' 'ELEM' 'CUB8' ;
 
** Maillage
  p1      = 0. 0. 0. ;
  p2      = 0. long 0. ;
  l12     = DROI 1 p1 p2 ;
  sgauche = l12 TRAN 1 (0. 0. haut) ;
  mail    = sgauche VOLU 'TRAN' 1 (long 0. 0.) ;
  sdroite = mail FACE 2 ;
  env1    = ENVE mail ;
  sbas    = env1 ELEM 5 ;
  shaut   = env1 ELEM 2 ;
  sdevant = env1 ELEM 4 ;
  sderrie = env1 ELEM 3 ;
  p3      = mail POIN 'PROC' (0. 0. haut) ;
  mes1    = MESU mail ;
*nh145313
cadr1 = COUL ((0. (long + 5.E-3) (haut + 5.E-3)) ET (long (long + 5.E-3) (haut + 5.E-3))) 'BLAN' ;
rep1 = @REPERE (-0.16 -0.16 0.) (PROG 0.3 0.3 0.3) 'TURQ' ;
SI ITRAC1 ;
  TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sgauche COUL 'VERT') ET (sdroite COUL 'ROUG')) 'TITR' '[3D V] Maillage - sgauche, sdroite' ;
  TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sbas COUL 'VERT') ET (shaut COUL 'ROUG')) 'TITR' '[3D V] Maillage - sbas, shaut' ;
  TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sdevant COUL 'VERT') ET (sderrie COUL 'ROUG')) 'TITR' '[3D V] Maillage - sdevant, sderrie' ;
  TRAC 'QUAL' (cadr1 ET rep1 ET mail ET ((sgauche ET sbas ET sdevant) COUL 'VERT') ET ((sdroite ET shaut ET sderrie) COUL 'ROUG')) 'TITR' '[3D V] Maillage' ;
FINSI ;
 
** Modele et caracteristiques materiau
  mo = MODE mail 'MECANIQUE' 'ELASTIQUE' 'ENDOMMAGEMENT' 'MAZARS' ;
  ma = MATE mo 'YOUN' you 'NU' nu 'KTR0' epd0 'ACOM' ac 'BCOM' bc 'ATRA' at 'BTRA' bt 'BETA' beta ;
 
** Blocages
  blhaut = BLOQ 'UZ' shaut ;
  blrig  = (BLOQ 'UX' sgauche) ET (BLOQ 'UY' sdevant) ET (BLOQ 'UZ' sbas) ;
  bl     = blhaut ET blrig ;
 
** Chargements (plusieurs pressions imposees, deplacement impose)
  evc1   = EVOL 'MANU' (PROG 0. 0.5 1.) (PROG 0. 1. 1.) ;
  lcoul  = MOTS 'BLEU' 'ORAN' 'VERT' 'ROUG' ;
  evtot0 = VIDE 'EVOLUTIO' ;
  evtot1 = VIDE 'EVOLUTIO' ;
  evtot2 = VIDE 'EVOLUTIO' ;
  npres = DIME lpres ;
  REPE b0 npres ;
* On fait un premier calcul avec seulement la pression imposee
    pre1 = EXTR lpres &b0 ;
*nh145313
*    fpr  = PRES 'MASS' mo (sdroite ET sderrie ET shaut) pre1 ;
    fprx = PRES 'MASS' mo sdroite pre1 ;
    fpry = PRES 'MASS' mo sderrie pre1 ;
    fprz = PRES 'MASS' mo shaut pre1 ;
    fpr = fprx ET fpry ET fprz ;
    chap = CHAR 'MECA' fpr evc1 ;
* Resolution 1 : mise en pression seulement
    t                               = TABL ;
    t . 'MODELE'                    = mo ;
    t . 'CARACTERISTIQUES'          = ma ;
    t . 'BLOCAGES_MECANIQUES'       = blrig ;
    t . 'CHARGEMENT'                = chap ;
    t . 'TEMPS_CALCULES'            = PROG 0. 'PAS' 0.1 0.5 ;
    t . 'MOVA'                      = MOT 'D' ;
    t . 'MES_SAUVEGARDES'           = TABL ;
    t . 'MES_SAUVEGARDES' . 'DEFTO' = VRAI ;
    PASAPAS t ;
* Resolution 2 : pression + ajout du deplacement impose
    dihaut = DEPI blhaut -1. ;
    uz0    = ABS (EXTR (t . 'DEPLACEMENTS' . 5) 'UZ' p3) ;
    evc2   = EVOL 'MANU' (PROG 0.5 1.) (PROG uz0 (umax - uz0)) ;
    chadi  = CHAR 'DIMP' dihaut evc2 ;
*nh145313
** Trace des blocages et du chargement
    re0 = @REPERE (-0.16 -0.16 0.) (PROG 0.3 0.3 0.3) ;
    mor = MODE re0 'MECANIQUE' 'BARR' ;
    mar = MATE mor 'YOUN' 1. 'NU' 1. 'SECT' 1. ;
    rir = RIGI mor mar ;
    vprx = VECT fprx 'FORC' 'VERT' 1.2E-6 ;
    vpry = VECT fpry 'FORC' 'VERT' 1.2E-6 ;
    vprz = VECT fprz 'FORC' 'VERT' 1.2E-6 ;
    vdiz = VECT dihaut ' ' ' ' 'FLX' 'ROUG' 3.E-2 ;
    tit0 = CHAI '[3D V] Blocages et chargement Uimp et Pres.imp =' pre1 ' Pa' ;
    SI ITRAC1 ;
      TRAC ((RIGI mo ma) ET bl ET rir) (vprx ET vpry ET vprz ET vdiz) 'NOLE' 'TITR' tit0 ;
    FINSI ;
    t . 'BLOCAGES_MECANIQUES'       = bl ;
    t . 'CHARGEMENT'                = chap ET chadi ;
    t . 'TEMPS_CALCULES'            = PROG 0.505 'PAS' 0.005 1. ;
    PASAPAS t ;
*    SI ITRAC1 ;
*      tit1 = CHAI '[3D V] UZ vs Temps - P =' ' ' pre1 ;
*      DESS (EVOL 'TEMPE' t 'DEPLACEMENTS' 'UZ' p3) 'TITR' tit1 ;
*      tit1 = CHAI '[3D V] SMZZ vs Temps - P =' ' ' pre1 ;
*      DESS (EVOL 'TEMP' t 'CONTRAINTES' 'SMZZ' 1 1 1) 'TITR' tit1 ;
*    FINSI ;
 
** Post traitement :
* courbes : endommagement moyen vs temps
*           contrainte moyenne vs deformation moyenne
*           force de reaction vs deplacement impose
    tt = t . 'TEMPS' ;
    tc = t . 'CONTRAINTES' ;
    te = t . 'DEFORMATIONS' ;
    tv = t . 'VARIABLES_INTERNES' ;
    tu = t . 'DEPLACEMENTS' ;
    tr = t . 'REACTIONS' ;
    def0 = DEFO (cadr1 ET rep1 ET mail) (tu . 0) 0. ;
    ltps = PROG ;
    lend = PROG ;
    lsig = PROG ;
    leps = PROG ;
    ldep = PROG ;
    lrea = PROG ;
    REPE b1 (DIME tt) ;
      tps1 = tt . (&b1 - 1) ;
      end1 = (INTG mo (tv . (&b1 - 1)) 'D')    / mes1 ;
      sig1 = (INTG mo (tc . (&b1 - 1)) 'SMZZ') / mes1 ;
      eps1 = (INTG mo (te . (&b1 - 1)) 'EPZZ') / mes1 ;
      u1   = EXTR (tu . (&b1 - 1)) 'UZ' p3 ;
      rea1 = 0. ;
      SI ((NBEL (EXTR (tr . (&b1 - 1)) 'MAIL')) > 0) ;
        rea1 = @TOTAL (tr . (&b1 - 1)) sbas 'FZ' ;
      FINSI ;
      ltps = ltps ET tps1 ;
      lend = lend ET end1 ;
      lsig = lsig ET sig1 ;
      leps = leps ET eps1 ;
      ldep = ldep ET u1 ;
      lrea = lrea ET rea1 ;
    FIN b1 ;
    evtot0 = evtot0 ET (EVOL (EXTR lcoul &b0) 'MANU' 'Temps' ltps 'D'    lend) ;
    evtot1 = evtot1 ET (EVOL (EXTR lcoul &b0) 'MANU' 'EPZZ'  leps 'SMZZ' lsig) ;
    evtot2 = evtot2 ET (EVOL (EXTR lcoul &b0) 'MANU' 'UZ'    ldep 'FZ'   lrea) ;
    tpre . &b0 = CHAI 'FORMAT' '(F3.1)' 'P=' (pre1*1.E-6) '_MPa' ;
    tleg . 'TITRE' . &b0 = CHAI 'Calcul_' tpre . &b0 ;
*   deformee
    REPE b2 (DIME t . 'TEMPS') ;
      tps1 = t . 'TEMPS' . (&b2 - 1) ;
*     trace de la deformee (pour controle visuel)
      def1 = DEFO mail (tu . (&b2 - 1)) 10. 'ROUG' ;
      tit1 = CHAI '[3D V] Deformee au temps' ' ' tps1 ;
      SI ITRAC1 ;
*        TRAC (def0 ET def1) 'TITR' tit1 ;
      FINSI ;
    FIN b2 ;
    SI ITRAC1 ;
      TRAC (def0 ET def1) 'TITR' tit1 ;
    FINSI ;
  FIN b0 ;
 
** Donnees experimentales de reference (FdP)
si (resexp);
  evxp0 = VIDE 'EVOLUTIO' ;
  tleg . (npres + 1) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 1) = CHAI 'Ref_Exp_' tpre . 1 ;
  tleg . (npres + 2) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 2) = CHAI 'Ref_Exp_' tpre . 2 ;
  tleg . (npres + 3) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 3) = CHAI 'Ref_Exp_' tpre . 3 ;
  tleg . (npres + 4) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 4) = CHAI 'Ref_Exp_' tpre . 4 ;
* Courbes Contrainte vs Deformation  
  txp  = LIRE 'CSV' FIC1 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'BLEU' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  txp  = LIRE 'CSV' FIC2 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'ORAN' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  txp  = LIRE 'CSV' FIC3 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'VERT' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  txp  = LIRE 'CSV' FIC4 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'ROUG' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
fins;
** Trace des courbes pour les differents niveaux de pression
  SI ITRAC1 ;
    DESS evtot0 'TITR' '[3D V] Endommagement vs Temps'    'LEGE' tleg ;
    SI RESEXP ;
      DESS (evtot1 ET evxp0) 'TITR' '[3D V] Contrainte vs Deformation' 'LEGE' tleg ;
    SINON ;
      DESS evtot1 'TITR' '[3D V] Contrainte vs Deformation' 'LEGE' tleg ;
    FINSI ;
    DESS evtot2 'TITR' '[3D V] Reaction vs Deplacement'   'LEGE' tleg ;
  FINSI ;
*nh145313
** Comparaison Calcul / Reference sur l'aire sous la courbe Valeur absolue de l'Ecart relatif en Contrainte vs Deformation
si (resexp);
  tbid = TABL ;
  tbid . 'TITRE' = TABL ;
  tbid . 1 = 'MARQ PLUS' ;
  tbid . 'TITRE' . 1 = 'Cal.init.' ;
  tbid . 2 = 'MARQ ETOI' ;
  tbid . 'TITRE' . 2 = 'Ref.exp.' ;
  tbid . 3 = 'MARQ CROI' ;
  tbid . 'TITRE' . 3 = 'Cal.ipol.' ;
  OPTI ECHO 0 ;
  SAUT 1 LIGN ;
  MESS ' **************** C A S  #1  :  3 D   V O L U M I Q U E ****************';
  SAUT 1 LIGN ;
  REPE b2 (DIME evxp0) ;
    evexp = EXTR evxp0  'COUR' &b2 ;
    evcal = EXTR evtot1 'COUR' &b2 ;
    xexp = ENLE (EXTR evexp 'ABSC') 1 ;
    yexp = ENLE (EXTR evexp 'ORDO') 1 ;
    xcal = ENLE (EXTR evcal 'ABSC') 1 ;
    ycal = ENLE (EXTR evcal 'ORDO') 1 ;
    xcal2 = xexp ;
    ycal2 = IPOL xcal2 evcal ;
    evcal2 = EVOL MANU 'EPZZ' xcal2 'SMZZ' ycal2 ;
    ler1 = ABS ((ycal2 - yexp) / yexp) ;
    eer1 = EVOL 'ORAN' 'MANU' '|EPZZ|' (ABS xexp) '|Ec.rel|SMZZ' ler1 ;
    deps = ABS ((EXTR xexp (DIME xexp)) - (EXTR xexp 1)) ;
    mer1 = (INTG eer1) / deps ;
    tit1 = CHAI '[3D V]' ' ' (tpre . &b2) ' Val.abs.Ec.rel.|(Calc-Ref)/Ref| Contr. vs |Defo.|, moy.int.|Ecart|' ' ' mer1 ;
    SI ITRAC1 ;
      DESS eer1 'TITR' tit1 ;
    FINSI ;
    SI ITRAC1 ;
      DESS (evcal et evexp et evcal2) 'TITR' tit1 'LEGE' tbid ;
    FINSI ;
    MESS ' Pres.hydrostat.:' ' ' (tpre . &b2) ', Moy.int. Val.abs. Ecart relatif entre Calcul et Reference' ' ' mer1 ;
    SAUT 1 LIGN ;
  FIN b2 ;
  OPTI ECHO 1 ;
fins;
FINSI ;
 
 
 
 
**************** C A S  #2  :  2 D   A X I S Y M E T R I Q U E ****************
SI (EXIS lcas 2) ;
** Options generales
  OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA4' ;
 
** Maillage
  p1      = 0. 0. ;
  p2      = rayo 0. ;
  sbas    = DROI 1 p1 p2 ;
  mail    = sbas TRAN 1 (0. haut) ;
  shaut   = mail COTE 3 ;
  p3      = shaut POIN 'PROC' (0. haut) ;
  sdroite = mail COTE 2 ;
*nh145313
cadr1 = COUL ((0. (haut + 5.E-3)) ET (long (haut + 5.E-3))) 'BLAN' ;
rep1 = @REPERE (-0.1 -0.06) (PROG 0.15 0.15) 'TURQ' ;
SI ITRAC1 ;
  TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sbas COUL 'VERT') ET ((sdroite ET shaut) COUL 'ROUG')) 'TITR' '[2D Axi.] Maillage' ;
FINSI ;
 
** Modele et caracteristiques materiau
  mo = MODE mail 'MECANIQUE' 'ELASTIQUE' 'ENDOMMAGEMENT' 'MAZARS' ;
  ma = MATE mo 'YOUN' you 'NU' nu 'KTR0' epd0 'ACOM' ac 'BCOM' bc 'ATRA' at 'BTRA' bt 'BETA' beta ;
  zer = ZERO mo 'NOEUD' ;
  un  = zer + 1. ;
  mes1 = INTG mo un 'SCAL' ;
 
** Blocages
  blhaut = BLOQ 'UZ' shaut ;
  blrig  = BLOQ 'UZ' sbas ;
  bl     = blhaut ET blrig ;
 
** Chargements (plusieurs pressions imposees, deplacement impose)
  evc1   = EVOL 'MANU' (PROG 0. 0.5 1.) (PROG 0. 1. 1.) ;
  lcoul  = MOTS 'BLEU' 'ORAN' 'VERT' 'ROUG' ;
  evtot0 = VIDE 'EVOLUTIO' ;
  evtot1 = VIDE 'EVOLUTIO' ;
  evtot2 = VIDE 'EVOLUTIO' ;
  npres = DIME lpres ;
  REPE b0 npres ;
* On fait un premier calcul avec seulement la pression imposee
    pre1 = EXTR lpres &b0 ;
*nh145313
*    fpr  = PRES 'MASS' mo (sdroite ET shaut) pre1 ;
    fprr = PRES 'MASS' mo sdroite pre1 ;
    fprz = PRES 'MASS' mo shaut pre1 ;
    fpr = fprr ET fprz ;
    chap = CHAR 'MECA' fpr evc1 ;
* Resolution 1 : mise en pression seulement
    t                               = TABL ;
    t . 'MODELE'                    = mo ;
    t . 'CARACTERISTIQUES'          = ma ;
    t . 'BLOCAGES_MECANIQUES'       = blrig ;
    t . 'CHARGEMENT'                = chap ;
    t . 'TEMPS_CALCULES'            = PROG 0. 'PAS' 0.1 0.5 ;
    t . 'MOVA'                      = MOT 'D' ;
    t . 'MES_SAUVEGARDES'           = TABL ;
    t . 'MES_SAUVEGARDES' . 'DEFTO' = VRAI ;
    PASAPAS t ;
* Resolution 2 : pression + ajout du deplacement impose
    dihaut = DEPI blhaut -1. ;
    uz0    = ABS (EXTR (t . 'DEPLACEMENTS' . 5) 'UZ' p3) ;
    evc2   = EVOL 'MANU' (PROG 0.5 1.) (PROG uz0 (umax - uz0)) ;
    chadi  = CHAR 'DIMP' dihaut evc2 ;
*nh145313
** Trace des blocages et du chargement
    re0 = @REPERE (-0.1 -0.06) (PROG 0.15 0.15) ;
 
    mor = MODE re0 'MECANIQUE' 'BARR' ;
    mar = MATE mor 'YOUN' 1. 'NU' 1. 'SECT' 1. ;
    rir = RIGI mor mar ;
    vprr = VECT fprr 'FORC' 'VERT' 1.E-7 ;
    vprz = VECT fprz 'FORC' 'VERT' 1.E-7 ;
    vdiz = VECT dihaut ' ' 'FLX' 'ROUG' 3.E-2 ;
    tit0 = CHAI '[2D Axi.] Blocages et chargement Uimp et Pres.imp =' pre1 ' Pa' ;
    SI ITRAC1 ;
      TRAC ((RIGI mo ma) ET bl ET rir) (vprr ET vprz ET vdiz) 'NOLE' 'TITR' tit0 ;
    FINSI ;
    t . 'BLOCAGES_MECANIQUES'       = bl ;
    t . 'CHARGEMENT'                = chap ET chadi ;
    t . 'TEMPS_CALCULES'            = PROG 0.505 'PAS' 0.005 1. ;
    PASAPAS t ;
*    SI ITRAC1 ;
*      tit1 = CHAI '[2D Axi.] UZ vs Temps - P =' ' ' pre1 ;
*      DESS (EVOL 'TEMPE' t 'DEPLACEMENTS' 'UZ' p3) 'TITR' tit1 ;
*      tit1 = CHAI '[2D Axi.] SMZZ vs Temps - P =' ' ' pre1 ;
*      DESS (EVOL 'TEMP' t 'CONTRAINTES' 'SMZZ' 1 1 1) 'TITR' tit1 ;
*    FINSI ;
 
** Post traitement :
* courbes : endommagement moyen vs temps
*           contrainte moyenne vs deformation moyenne
*           force de reaction vs deplacement impose
    tt = t . 'TEMPS' ;
    tc = t . 'CONTRAINTES' ;
    te = t . 'DEFORMATIONS' ;
    tv = t . 'VARIABLES_INTERNES' ;
    tu = t . 'DEPLACEMENTS' ;
    tr = t . 'REACTIONS' ;
    def0 = DEFO (cadr1 ET rep1 ET mail) (tu . 0) 0. ;
    ltps = PROG ;
    lend = PROG ;
    lsig = PROG ;
    leps = PROG ;
    ldep = PROG ;
    lrea = PROG ;
    REPE b1 (DIME tt) ;
      tps1 = tt . (&b1 - 1) ;
      end1 = (INTG mo (tv . (&b1 - 1)) 'D')    / mes1 ;
      sig1 = (INTG mo (tc . (&b1 - 1)) 'SMZZ') / mes1 ;
      eps1 = (INTG mo (te . (&b1 - 1)) 'EPZZ') / mes1 ;
      u1   = EXTR (tu . (&b1 - 1)) 'UZ' p3 ;
      rea1 = 0. ;
      SI ((NBEL (EXTR (tr . (&b1 - 1)) 'MAIL')) > 0) ;
        rea1 = @TOTAL (tr . (&b1 - 1)) sbas 'FZ' ;
      FINSI ;
      ltps = ltps ET tps1 ;
      lend = lend ET end1 ;
      lsig = lsig ET sig1 ;
      leps = leps ET eps1 ;
      ldep = ldep ET u1 ;
      lrea = lrea ET rea1 ;
    FIN b1 ;
    evtot0 = evtot0 ET (EVOL (EXTR lcoul &b0) 'MANU' 'Temps' ltps 'D'    lend) ;
    evtot1 = evtot1 ET (EVOL (EXTR lcoul &b0) 'MANU' 'EPZZ'  leps 'SMZZ' lsig) ;
    evtot2 = evtot2 ET (EVOL (EXTR lcoul &b0) 'MANU' 'UZ'    ldep 'FZ'   lrea) ;
    tpre . &b0 = CHAI 'FORMAT' '(F3.1)' 'P=' (pre1*1.E-6) '_MPa' ;
    tleg . 'TITRE' . &b0 = CHAI 'Calcul_' tpre . &b0 ;
*   deformee
    REPE b2 (DIME t . 'TEMPS') ;
      tps1 = t . 'TEMPS' . (&b2 - 1) ;
*     trace de la deformee (pour controle visuel)
      def1 = DEFO mail (tu . (&b2 - 1)) 10. 'ROUG' ;
      tit1 = CHAI '[2D Axi.] Deformee au temps' ' ' tps1 ;
      SI ITRAC1 ;
*        TRAC (def0 ET def1) 'TITR' tit1 ;
      FINSI ;
    FIN b2 ;
    SI ITRAC1 ;
      TRAC (def0 ET def1) 'TITR' tit1 ;
    FINSI ;
  FIN b0 ;
 
** Donnees experimentales de reference (FdP)
si (resexp);
  evxp0 = VIDE 'EVOLUTIO' ;
  tleg . (npres + 1) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 1) = CHAI 'Ref_Exp_' tpre . 1 ;
  tleg . (npres + 2) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 2) = CHAI 'Ref_Exp_' tpre . 2 ;
  tleg . (npres + 3) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 3) = CHAI 'Ref_Exp_' tpre . 3 ;
  tleg . (npres + 4) = MOT 'MARQ CROI NOLI' ;
  tleg . 'TITRE' . (npres + 4) = CHAI 'Ref_Exp_' tpre . 4 ;
* Courbes Contrainte vs Deformation  
  txp  = LIRE 'CSV' FIC1 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'BLEU' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  txp  = LIRE 'CSV' FIC2 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'ORAN' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  txp  = LIRE 'CSV' FIC3 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'VERT' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  txp  = LIRE 'CSV' FIC4 'DEBU' 2 'SEPA' ',' ;
  evxp0 = evxp0 ET (EVOL 'ROUG' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
fins;
** Trace des courbes pour les differents niveaux de pression
  SI ITRAC1 ;
    DESS evtot0 'TITR' '[2D Axi.] Endommagement vs Temps'    'LEGE' tleg ;
    SI RESEXP ;
      DESS (evtot1 ET evxp0) 'TITR' '[2D Axi.] Contrainte vs Deformation' 'LEGE' tleg ;
    SINON ;
      DESS evtot1 'TITR' '[2D Axi.] Contrainte vs Deformation' 'LEGE' tleg ;
    FINSI ;
    DESS evtot2 'TITR' '[2D Axi.] Reaction vs Deplacement'   'LEGE' tleg ;
  FINSI ;
*nh145313
** Comparaison Calcul / Reference sur l'aire sous la courbe Valeur absolue de l'Ecart relatif en Contrainte vs Deformation
si (resexp);
  tbid = TABL ;
  tbid . 'TITRE' = TABL ;
  tbid . 1 = 'MARQ PLUS' ;
  tbid . 'TITRE' . 1 = 'Cal.init.' ;
  tbid . 2 = 'MARQ ETOI' ;
  tbid . 'TITRE' . 2 = 'Ref.exp.' ;
  tbid . 3 = 'MARQ CROI' ;
  tbid . 'TITRE' . 3 = 'Cal.ipol.' ;
  OPTI ECHO 0 ;
  SAUT 1 LIGN ;
  MESS ' **************** C A S  #2  :  2 D   A X I S Y M E T R I Q U E ****************';
  SAUT 1 LIGN ;
  REPE b2 (DIME evxp0) ;
    evexp = EXTR evxp0  'COUR' &b2 ;
    evcal = EXTR evtot1 'COUR' &b2 ;
    xexp = ENLE (EXTR evexp 'ABSC') 1 ;
    yexp = ENLE (EXTR evexp 'ORDO') 1 ;
    xcal = ENLE (EXTR evcal 'ABSC') 1 ;
    ycal = ENLE (EXTR evcal 'ORDO') 1 ;
    xcal2 = xexp ;
    ycal2 = IPOL xcal2 evcal ;
    evcal2 = EVOL MANU 'EPZZ' xcal2 'SMZZ' ycal2 ;
    ler1 = ABS ((ycal2 - yexp) / yexp) ;
    eer1 = EVOL 'ORAN' 'MANU' '|EPZZ|' (ABS xexp) '|Ec.rel|SMZZ' ler1 ;
    deps = ABS ((EXTR xexp (DIME xexp)) - (EXTR xexp 1)) ;
    mer1 = (INTG eer1) / deps ;
    tit1 = CHAI '[3D V]' ' ' (tpre . &b2) ' Val.abs.Ec.rel.|(Calc-Ref)/Ref| Contr. vs |Defo.|, moy.int.|Ecart|' ' ' mer1 ;
    SI ITRAC1 ;
      DESS eer1 'TITR' tit1 ;
    FINSI ;
    SI ITRAC1 ;
      DESS (evcal et evexp et evcal2) 'TITR' tit1 'LEGE' tbid ;
    FINSI ;
    MESS ' Pres.hydrostat.:' ' ' (tpre . &b2) ', Moy.int. Val.abs. Ecart relatif entre Calcul et Reference' ' ' mer1 ;
    SAUT 1 LIGN ;
  FIN b2 ;
  OPTI ECHO 1 ;
fins;
FINSI ;
 
 
 
 
FIN ;